Кто пробовал пользоваться бюджетным датчиком вредных газов MQ-135 для анализа концентрации углекислого газа CO₂ в воздухе, то сталкивались с неточностями в показаниях, с зависимостью от температуры окружающей среды, с трудностями калибровки и перевод в стандартные единицы PPM. Рассмотрим датчик  уровня углекислого газа MH-Z19, который и точнее и эргономичнее и удобнее.

Сперва просто подключим датчик к Arduino Nano, а ниже соберем прибор с дисплеем и датчиком температуры.

Необходимые материалы

• Arduino Nano
• Датчик MH-Z19
• Соединительные кабеля мама-мама

Подключения к ШИМ выходу

Скетч

Чтение показаний датчика с выхода PWM и вывод значений в монитор порта. Формулу для перевода синала ШИМ в PPM единицы можно найти в тех.описании датчика.

#define pwmPin 5
#define LedPin 13

int prevVal = LOW;
long th, tl, h, l, ppm;

void setup() {
  Serial.begin(9600);
  pinMode(pwmPin, INPUT);
  pinMode(LedPin, OUTPUT);
}

void loop() {
  long tt = millis();
  int myVal = digitalRead(pwmPin);

  //Если обнаружили изменение
  if (myVal == HIGH) {
    digitalWrite(LedPin, HIGH);
    if (myVal != prevVal) {
      h = tt;
      tl = h - l;
      prevVal = myVal;
    }
  }  else {
    digitalWrite(LedPin, LOW);
    if (myVal != prevVal) {
      l = tt;
      th = l - h;
      prevVal = myVal;
      ppm = 5000 * (th - 2) / (th + tl - 4);
      Serial.println("PPM = " + String(ppm));
    }
  }
}

Теперь соберем мобильный прибор для измерения уровня CO2, температуры и влажности. Так можно будем измерить показания как в помещении так и на улице.

Схема подключения

Скетч

Для переносного датчика MH-Z19 с дисплеем Nokia 5110. Потребуются библиотеки Adafruit_GFX_5110 и DHT11.

#include <SPI.h>
#include <Adafruit_GFX.h>
#include <dht11.h>
#include <Adafruit_PCD8544.h>
Adafruit_PCD8544 display = Adafruit_PCD8544(7, 6, 5, 4, 3);
dht11 DHT;
#define DHT11_PIN 8
#define pwmPin 2
#define LedPin 13

int prevVal = LOW, times = 0;
long th, tl, h, l, ppm;

void setup() {
  Serial.begin(9600);
  pinMode(pwmPin, INPUT);
  pinMode(LedPin, OUTPUT);
  display.begin();
  display.clearDisplay();
  display.setContrast(60);
  display.setTextSize(2);
  display.setTextColor(BLACK);
}

void loop() {
  long tt = millis();

  //чтение PWM от CO2
  int myVal = digitalRead(pwmPin);
  if (myVal == HIGH) {
    digitalWrite(LedPin, HIGH);
    if (myVal != prevVal) {
      h = tt;
      tl = h - l;
      prevVal = myVal;
    }
  }  else {
    digitalWrite(LedPin, LOW);
    if (myVal != prevVal) {
      l = tt;
      th = l - h;
      prevVal = myVal;
      ppm = 5000 * (th - 2) / (th + tl - 4);
      Serial.println("PPM = " + String(ppm));
      display.clearDisplay();
      display.setCursor(0, 0);
      if (ppm < 1000)
        display.println(String(ppm) + "ppm");
      else
        display.print(String(ppm) + "ppm");
      times++;

      if (times >= 3) {
        times = 0;
        int chk = DHT.read(DHT11_PIN);    // Чтение данных
        switch (chk) {
          case DHTLIB_OK:
            break;
          case DHTLIB_ERROR_CHECKSUM:
            display.println("Checksum error, \t");
            break;
          case DHTLIB_ERROR_TIMEOUT:
            display.println("Time out error, \t");
            break;
          default:
            display.println("Unknown error, \t");
            break;
        }
        // Выводим показания влажности и температуры
        display.print("Hum:");
        display.println(DHT.humidity, 1);
        display.print("Temp:");
        display.println(DHT.temperature, 1);
      }

      display.display();
    }
  }
}

Видео